• Bienvenue sur le forum de Paragon !
Bienvenue, Visiteur ! Connexion S’enregistrer


Note de ce sujet :
  • Moyenne : 5 (1 vote(s))
  • 1
  • 2
  • 3
  • 4
  • 5
Compendium macros PvP
#1
Compendium de macros WoTLK PvP

Bienvenue sur ce guide qui a pour but de proposer un échantillon assez large des macros qui peuvent être intéressante en pvp que ce soit pour débutant ou joueurs plus expérimentés. Certaines de ces macros peuvent aussi être utile dans un but de PvE donc il n'est pas inintéressant à lire pour les adeptes de raid. Si vous avez des idées de macros ou des commentaires n'hésitez pas à m'en faire part, je pourrais rajouter ou modifier ce compendium au fur et à mesure.
Dans un premier temps nous verrons comment vous pouvez créer vos propres macros, et dans un deuxième temps je vous livrerais un échantillon exhaustif de mes macros par classes.


I- Bases

Pour commencer nous allons débuter par quelques macros très simples, les focus, les player, les party1/2/3, les arena1/2/3 les stopcasting et les start/stopattack.
Petit addendum avant de commencer, le @ est un remplacement pour "target=" donc un @target par exemple veut dire target=target.

https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">
Citation :. Macro focus :

/cast [target=focus] "sort"


Cette macro permet très simplement de lancer un sort sur votre focus. 

Citation :. Macro player :

/cast [target=player] "sort"

Cette macro permet de lancer un sort sur votre personnage sans avoir besoin de vous cibler spécialement.

Citation :. Macro party# :

/cast [target=party#] "sort"  (remplacer # par le numéro 1/2/3/etc pour cibler la personne voulue)

Cette macro permet de lancer un sort sur un membre de votre groupe (party1 étant la première personne du groupe, party2, la deuxième et ainsi de suite).

Citation :. Macro arena# :

/cast [target=arena#] "sort" (remplacer # par le numéro 1/2/3 pour cibler la personne voulue)

Cette macro permet de lancer un sort sur un des ennemis en arène (arena 1 à 3 sont déterminés par leur ordre dans l'interface blizzard, les petits portraits à droite dans une arène, arena 1 étant le plus en haut jusqu'à arena 3 en bas).

Citation :. Rajouter une ligne avec /stopcasting dans une macro permet d'arrêter une incancation

Exemple :
/stopcasting
/cast Vague de Soin

Appuyer une première fois sur la macro permet un check pour voir si rien n'est en train d'être cast et dans ce cas interrompt l'incantation. Puis ré-appuyer sur la macro lance ensuite vague de soin. Attention : Si vous spammez la macro, par conséquence le sort sera interrompu en permanence.
Vous pouvez mettre un /stopcasting sur des sorts ne nécéssitant pas de gcd pour permettre de les lancer pendant vos cast si besoin.
(Contresort/cisaille de vent/etc etc)

Citation :. Rajouter une ligne avec /startattack ou /stopattack permet de commencer à initier des auto attack ou de les stopper.
De plus rajouter une ligne avec startattack permet aussi de cibler l'ennemi le plus proche de vous.

Exemple :
/startattack
/cast Éclair

Appuyer sur la macro permettra de mettre en cible l'ennemi le plus proche et de commencer à incanter Éclair

Exemple ²:
/stopattack
/cast Suriner

Appuyer sur la macro permettra de Suriner l'ennemi tout en étant sûr qu'aucun coup blanc ne partira.

II- Modifier et Mouseover

Dans cette partie nous allons nous pencher sur les macros demandant des "modifier" et les macros "mouseover".
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

Citation :. Rajouter un modifier dans une macro permet de lancer un sort sur une cible différente ou un autre sort si le modifier est pressé. Les modifiers sont "alt", "ctrl", "shift". Utilisez ceux qui vous plaisent.
Voici plusieurs exemples.

Exemple 1 :
/cast [nomod, @player][mod:alt, @party1] "sort"

Si cette macro a pour raccourci A et que je presse A, le sort se lancera sur mon personnage. Si je presse ALT + A il se lancera sur le premier membre de mon groupe.

Exemple 2 :
/cast [mod:alt] Métamorphose; [mod:ctrl] Éclair de givre(rang 1); Éclair de givre(rang 10)

Si cette macro a pour raccourci S et que je presse S, le sorte éclair de givre rang 10 se lancera. Si je presse ALT + S, le sort métamorphose se lancera. Si je presse CTRL + S, le sort éclair de givre rang 1 se lancera.

Citation :. Le mouseover permet d'utiliser le curseur de la souris comme cible.
Il y a plusieurs utilités possibles, comme passer en target ou en focus la personne que vous ciblez à la souris sans cliquer sur elle.


Exemple :
/target mouseover ou /focus mouseover

Ou tout simplement de lancer des sorts sans cibler une personne et juste grâce au curseur de la souris

Exemple :
/cast [target=mouseover] "Sort"

 
III- Macros Pet

Dans cette partie nous allons voir des macros pour changer le statut du familier, pour lancer des sorts directement sur un familier allié ou pour aider à casser des totems avec votre familier.

https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

Citation :. Les commandes de macros pour changer le familier de status sont les suivantes. Vous pouvez les incorporer dans des macros basiques ou les mettre à part.

/petpassive : passe le familier en passif
/petaggressive : passe le familier en agressif
/petdefensive : passe le familier en defensif
/petattack : Ordonne au familier d'attaquer
/petfollow : Ordonne au familier de nous suivre
/petstay : Ordonne au familier de rester sur place

Exemple :
/petfollow
/cast Guérison du familier

La macro lance le sort guérision du familier tout en ordonnant le pet de nous suivre.

Citation :. Macro pour lancer des sorts sur les familiers alliés sans les cibler.

/cast [@party#pet] "Sort"  (Remplacer le # par le numéro 1/2/3/etc pour cibler la personne du groupe voulue)

Lance le sort choisi sur le familier du membre du groupe choisi.

Citation :. Macro pour "stomp" les totems avec les familiers.

/pettack mouseover

Très simplement cette macro permet d'envoyer le familier attaqué la cible sur laquelle se trouve votre curseur de souris
En voici une version un peu plus poussée :

/petfollow [@pettarget,exists]
/petattack [@mouseover,harm,nodead][@pettarget,noexists]


Elle permet en appuyant une fois sur la macro d'envoyer votre pet attaquer votre target (mais choisira en priorité votre "mouseover" si vous en avez un) et en appuyant une seconde fois sur la macro votre pet revient vous suivre.


IV- Stance, Form, Etc.

Dans cette partie nous allons voir comment lancer des macros spécifiques à votre stance (rogue/war) ou à votre forme (drood).
Il faut savoir tout d'abord à quoi correspondent chaque stance/form pour les classes

. Guerrier :
Stance 1 : Posture de combat
Stance 2 : Posture défensive
Stance 3 : Posture berserker

. Druide :
Stance 0 : Forme humaine
Stance 1 : Forme d'ours
Stance 2 : Forme de voyage 
Stance 3 : Forme de chat
Stance 4 : Forme de sélénien
Stance 5 : Forme d'arbre

. Rogue :
Stance 0 : Non camouflé
Stance 1 : Camouflé
Stance 2 : Disparition (inutile la plupart du temps vu que la stance 1 camouflé marche aussi)
Stance 3 : Danse de l'ombre

https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

Citation :. Macro changement de stance couplé avec un sort dans la stance voulu

Exemple 1 :
/cast [nostance:1] Forme d'ours redoutable(Changeforme)

/cast [stance:1, nomod] Charge farouche (ours)
/cast [stance:1, mod:alt, @focus] Charge farouche (ours)

Cette macro permet de cast sa forme d'ours redoutable si on n'est pas avec la bonne forme et de lancer une charge ours ensuite (avec en plus un modifier ajouté pour chosir entre son target et son focus)

Exemple 2 :
/cast [stance:1/2] Posture berserker
/cast [stance:3] Volée de coups


Par exemple cette macro permet de passer en stance zerk si vous ne l'êtes pas et puis si vous l'êtes de lancer le sort volée de coups directement.
Vous pourrez voir d'autres exemples dans ma partie macro perso.



V- Autres fonctions de macros diverses

Dans cette partie nous allons voir plusieurs fonctions diverses de macros et comment on peut les appliquer. Ce sera la dernière grosse partie avant de passer à mes macros personnelles
Fonctions qui seront concernées : "swapactionbar", "!", "/cancelaura", "exists/noexists" et pour finir les macros /equip 
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

Citation :. Fonction Swapactionbar
Cette macro permet tout simplement de switcher d'une action de barre à une autre et vous permet donc d'avoir accès à plus de possibilités de sorts, de choix selon votre mode de jeu (votre action de barre par défaut est 1). Voici la macro :

Exemple :
/swapaction bar 1 2


Cette macro swap tout simplement votre barre d'action d'1 à 2 en appuyant une fois et reswap en appuyant une deuxième fois.

Citation :. Fonction !
Cette fonction permet de spam des sorts qui ont un effet on/off sans que l'effet "off" s'active. Voici quelques exemples

Exemple 1 :
/cast !Camouflage

Cette macro permet de spam le camouflage sans faire l'erreur de rentrer en fufu et d'en sortir directement après

Exemple 2 :
/cast !Dissipation de masse

Cette macro permet de spam le sort dissipation de masse sans perdre le cercle vert qui permet de déterminer la zone à dissiper.

Citation :. /cancelaura

Cette fonction permet de cancel une aura (comme tempête de lames, dispersion, bloc de glace, etc) et peut avoir plusieurs utilités (la première étant de ne pas rester bloqué 8s dans votre bloc de glace si vous avez besoin d'en sortir)
Vous pouvez soit mettre cette ligne sur d'autres sorts ou sur le même sort qui pose l'aura mais dans ce cas attention à ne pas spam votre macro sinon vous ferez des cancels non voulus.

Exemple 1 :
/cancelaura Dispersion
/cast Mot de pouvoir : Bouclier(Rang 14)

Qui permet de se sortir de la dispersion pour lancer un bouclier par exemple

Exemple 2 :
/cast Dispersion
/cancelaura Dispersion

Cette macro permet en un seul raccourci de lancer sa dispersion et du même bouton de l'enlever. Comme dit plus haut attention si vous spammez votre raccourci vous risquez de virez votre dispersion directement.

Citation :. Exists/Noexists

Cette fonction de macro permet de mettre des conditions supplémentaires qui sont tout simplement le "si ça existe" fais ça ou "si ça n'existe pas" fais ceci. Il en existe des déclinaisons comme le "equipped/noequipped" ou le "pet/nopet" et d'autres. Voici quelques exemples simples de comment utiliser ce genre de macro.

Exemple 1 :

/cast [@focus, exists][@target] "Sort"

En utilisant cette macro vous lancerez un sort sur votre focus si vous en avez un, sinon vous le lancerez sur votre cible.

Exemple 2 :

/cast [@focus,exists][@target, exists][@player] "Sort"

Cette macro lancera un sort en priorité sur votre focus si vous en avez un sinon en priorité sur votre cible si vous en avez une et sinon elle lancera le sort sur vous même.


Citation :. /Equip
Tout simplement ce sont des macros qui font appel aux équipements, on les utilise souvent en pvp avec les armes
On peut les écrire en /equip ou en /equisplot pour être plus précis (sachant que equipslot 16 est la main droite ou Main Hand et equipslot 17 la main gauche ou Off Hand). 

Exemple :
/equipslot 16 "Arme X"
/equipslot 16 "Arme Y"

En utilisant une fois cette macro vous équipez l'arme X et en appuyant une deuxième fois vous équipez l'arme Y.



VI- Fin de la première partie et transition.

Pour finir cette première partie je vais aborder le #showtooltip qui permet tout simplement d'avoir la petite icône correspondante au sort voulu en icône de macro.
Il suffit soit de mettre #showtooltip en premier ligne de votre macro ou #showtooltip "Sort" si vous voulez avoir un sort précis
Exemple :
#showtooltip Hymne divin(Rang 1)
/cast Focalisation améliorée
/cast Hymne divin(Rang 1)
Cette macro aura donc comme icône l'hymne divin même si c'est la focalisation améliorée qui est utilisée en premier dans la macro.

Certains aspects des macros n'ont pas été abordés comme par exemple les /castsequence que ce soit car je ne les utilise que très peu (ou pas du tout) dans mes macros ou d'autres (comme les [harm]/[help]) car il me faudrait encore trop de pages. Et que de toutes façons vous pourrez en trouver certaines dans la deuxième partie qui consiste en une liste de macros personnelles pour chaque classes.
 
Répondre
#2
VII- Partie deux, liste de macros

A) Macro d'utilité générales
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet d'augmenter la distance de caméra maximale :
/script SetCVar ("cameraDistancemax" ,50)

.Permet de bouger les frames de l'équipe d'arène ennemie :
/run local f=ArenaEnemyFrame1; f:SetUserPlaced(true) f:SetMovable(true) f:EnableMouse(true) f:RegisterForDrag("LeftButton") f:SetScript("OnDragStart",f.StartMoving) f:SetScript("OnDragStop",f.StopMovingOrSizing)

. Permet de mettre son target en focus :
/focus

. Permet d'inverser le target et le focus :
/cleartarget [target=target,dead]
/clearfocus [target=focus,dead]
/target focus
/cleartarget [target=focus,noexists]
/targetlasttarget
/focus target
/targetlasttarget

. Permet de target un ennemi en arène (remplacez le # par 1/2/3) :
/target arena#

. Permet de mettre en focus un ennemi en arène (remplacez le # par 1/2/3) :
/focus arena#

. Permet de cibler un coéquipier (remplacez le # par 1/2/3)
/target party#

. Permet de lancer un sort sur un ennemi spécifique en arène (remplacez le # par 1/2/3) :
/cast [target=arena#] "Sort"

. Permet de lancer un sort sur un allié spécifique (remplacez le # par 1/2/3/etc) :
/cast [target=party#] "Sort"

.Permet de lancer un sort sur le familier de l'allié choisi (Remplacez le # par le numéro 1/2/3/etc pour cibler la personne du groupe voulue) :
/cast [@party#pet] "Sort"


. Permet d'utiliser le tir/lancer sur mouseover en priorité puis target ou focus :
#showtooltip Tir
/cast [target=mouseover, exists][mod:alt, @focus][] Tir


. Permet de focus son mouseover :
/focus mouseover

. Permet de cibler l'ennemi le plus proche puis de lancer un sort (mettre le sort de votre choix) :
/startattack
/cast "Sort"

. Macro pour tenter de brain les vanish rogues (permet de cast un sort à incantation/cible unique si vous avez une cible et si vous n'en avez plus, suite à un vanish par exemple, le sort devient un sort à aoe) :
/cast [@target, exists] "Sort à cible unique"
/cast [@target, noexists] "Sort à Aoe"


. Macro pour brain le feindre la mort des hunts (Quand le hunt fd il suffit de appuyer une seconde fois sur la macro pour le recibler directement) :
#showtooltip
/cast [@target, exists] "Sort"
/targetlasttarget [noexists]

. Macro permettant d'envoyer son familier attaquer le mouseover (priorité) ou votre cible en appuyant une fois et de le ramener vers vous en appuyant une deuxième fois :
/petfollow [@pettarget,exists]
/petattack [@mouseover,harm,nodead][@pettarget,noexists]


. Macro pour desactiver un sort auto d'un familier et de le réactiver en un clic :
/petautocasttoggle "nom du sort"
/petautocastoff "nom du sort"
/petautocaston "nom du sort"


B) Chaman (principalement elem)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de cs target :
/stopcasting
/cast Cisaille de vent

. Permet de cs focus :
/stopcasting
/cast [target=focus] Cisaille de vent


. Permet de dispell poisons sur soi ou son coep :
#showtooltip Guérison des toxines
/cast [nomod, @player][mod:alt, @party1] Guérison des toxines

. Permet de Maléfice le target ou le focus (peut avoir un /stopcasting en première ligne si la macro n'est pas spammé) :
#showtooltip Maléfice
/cast [nomod, @target][mod:alt, @focus] Maléfice

. Permet de stopcast et dispell le target ou le focus
#showtooltip

/stopcasting
/cast [nomod, @target][mod:alt, @focus] Expiation(Rang 2)

. Permet de poser un totem en glèbe même pendant un cast :
/stopcasting
/cast Totem de glèbe


. Macro enhance pour switch d'enchant Off Hand (mettez l'enchant que vous voulez)
/cast [@none] Arme de givre(Rang 9)
/use 17
/click StaticPopup1Button1

. Macro pour les loups fantômes et les faire attaquer le mouseover en priorité puis son target ou son focus :
/cast Esprit farouche
/petattack [@mouseover,harm][mod:alt, @focus][]


. Macro pour le stun loup target ou focus :
/cast [nomod, @target][mod:alt, @focus] Sonner(Rang 1)

. Macro pour lancer le sprint des loups :
/cast Marche de l'esprit


C) Prêtre (Discipline/Ombre)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de se shield ou son party1 (remplacez le mot de pouvoir bouclier par renovation/prière de guérison/soin rapides et vous avez d'autres macros que j'utilise en prêtre) :
#showtooltip Mot de pouvoir : Bouclier(Rang 14)
/cast [nomod][mod:alt, @party1] Mot de pouvoir : Bouclier(Rang 14)


. Permet de se pénitence (remplacez player par party1/2 etc pour soignez votre allié voulu) :
/cast [target=player] Pénitence(Rang 4)

. Permet de mettre l'anti fear sur soi, son coep ou son pet :
#showtooltip Gardien de peur
/cast [nomod, @player][mod:alt, @party1][mod:ctrl, @pet] Gardien de peur

. Permet de dissipation de la magie sur soi (remplacez player par party1/2 etc pour dispell votre allié voulu) :
#showtooltip
/cast [target=player] Dissipation de la magie(Rang 2)

. Permet d'Hymne divin sans coûter de mana :
#showtooltip Hymne divin(Rang 1)
/cast Focalisation améliorée
/cast Hymne divin(Rang 1)

. Permet de se pain sup (remplacez player par party1/2 etc pour pain sup votre allié voulu :
#showtooltip Suppression de la douleur
/cast [target=player] Suppression de la douleur


. Permet de swd target target :
#showtooltip Mot de l'ombre : Mort(Rang 4)
/stopcasting
/cast Mot de l'ombre : Mort(Rang 4)

. Permet de swd focus :
#showtooltip Mot de l'ombre : Mort(Rang 4)
/stopcasting
/cast [target=focus] Mot de l'ombre : Mort(Rang 4)

. Permet de swd la personne nous lançant le premier sort si on a pas de target (utile contre les sorts instants comme les blind/gouge/succube) :
#showtooltip Mot de l'ombre : Mort(Rang 4)
/stopcasting [harm]
/cast [target=mouseover, exists] [target, exists] Mot de l'ombre : Mort(Rang 4)

. Permet de spam Mass Dispell :
#showtooltip Dissipation de masse
/cast !Dissipation de masse


. Permet de cage en prio la gargouille :
#showtooltip Entraves des morts-vivants(Rang 3)
/target [harm] Gargouille d'ébène
/cast Entraves des morts-vivants(Rang 3)
/targetlasttarget

. Permet d'utiliser sa dispersion et de cancel au moment voulu :

/cast Dispersion
/cancelaura Dispersion

. Permet d'ombrefiel, d'ordonner à son familier d'attaquer et d'ombremarche dans la même macro :
/cast Ombrefiel
/petattack
/cast Ombremarche

. Permet d'ombrefiel et de dispell son pet dans la même macro :
/cast [nopet] Ombrefiel
/petattack
/cast [target=pet, pet] Dissipation de la magie(Rang 2)

. Permet d'ombremarche et d'attaquer le mouseover en priorité puis le target ou le focus :
#showtooltip Ombremarche
/cast [target=mouseover, exists][nomod, @target][mod:alt, @focus] Ombremarche
/petattack [@mouseover,harm][mod:alt, @focus][]

. Permet de dispell son ombrefiel :
/cast [target=pet] Dissipation de la magie(Rang 2)

. Permet de silence (à remplacer par disarm pour obtenir une autre macro utile) target ou focus :
/cast [nomod][mod:alt, @focus] Silence

. Permet de fouet mental focus :
/cast [target=focus] Fouet mental(Rang 9)

. Permet d'incandescence mental le mouseover ou le target :

#showtooltip Incandescence mentale(Rang 2)
/cast [target=mouseover, exists][target, exists] Incandescence mentale(Rang 2)



. Permet de soin de lien le mouseover ou le party1 :
#showtooltip Soins de lien(Rang 3)
/cast [target=mouseover, exists] [target, party1] Soins de lien(Rang 3)


. Permet de cancel aura le contrôle mental :
/cancelaura Contrôle mental


D) Mage (Frost principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de cast un éclair de givre sur target (en pressant alt passe votre focus en target et lance un éclair de givre) et passe votre familier en combat :
#showtooltip
/cast [target=focus, mod:alt] Eclair de givre(Rang 16); Eclair de givre(Rang 16)
/startattack
/cast [nocombat] attack
/lancer Eclair d'eau

. Permet d'éclair de givre rang 1 le mouseover en priorité puis le target ou le focus (avec alt) :
#showtooltip Eclair de givre(Rang 1)
/cast [target=mouseover, exists][target, exists][mod:alt, @focus] Eclair de givre(Rang 1)


. Permet de congélation le target ou le focus :
#showtooltip Congélation
/cast [nomod, @target][mod:alt, @focus] Congélation


. Permet de sheep le target ou le focus tout en rendant le pet passif et en stoppant son cast d'éclair d'eau :
#showtooltip Métamorphose(Rang 4)
/petpassive
/petfollow
/cast [nomod, @target][mod:alt, @focus] Métamorphose(Rang 4)

. Permet de définir sa cible de sheep en tant que focus puis de sheep son focus, si le focus est mort passe son target actuel en focus :
#showtooltip Métamorphose(Rang 4)
/castrandom [@focus, exists, nodead][] Métamorphose(Rang 4)
/stopmacro [@focus,exists,nodead]
/focus [@target, exists, nodead]

. Permet d'invisi et de garder son pet à sa place pour ne pas qu'il vous suive :
/cast Invisibilité
/petstay


. Permet de javelot le mouseover en priorité puis la cible :
#showtooltip Javelot de glace(Rang 3)
/cast [target=mouseover, exists] [target, exists] Javelot de glace(Rang 3)


. Permet de silence target :
#showtooltip
/stopcasting
/cast Contresort

. Permet de silence focus :
#showtooltip Contresort
/stopcasting
/cast [target=focus] Contresort

. Permet de vol de sort sur son target ou focus tout en cancelant l'aura de la main de sacrifice si récuperé :
/stopcasting
/cast [nomod, @target][mod:alt, @focus] Vol de sort
/cancelaura Main de sacrifice

. Permet d'invoquer son familier et de geler dans la même macro :
#show Invocation d'un élémentaire d'eau
/lancer Invocation d'un élémentaire d'eau
/petpassif
/cast Gel

. Permet d'utiliser le sort de gel du familier :
#show gel
/cast gel


. Permet de bloc de glace et de cancelaura le bloc de glace en appuyant de nouveau :
/stopcasting
/cast bloc de glace
/cancelaura bloc de glace

. Permet de dispell les malés sur soi même ou son coep :
/cast [nomod, @player][mod:alt, @party1] Délivrance de la malédiction

. Permet de spam sa macro Blizzard sans perdre la zone verte :
/cast !Blizzard(Rang 9)



E) Chevalier de la mort (Udk principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de lancer le changeliche et de cancelaura sur la même macro :
/cast Changeliche
/cancelaura Changeliche

. Permet de poigne de la mort target ou focus :
#showtooltip
/cast [nomod, @target][mod:alt, @focus] Poigne de la mort

. Permet de strangulation target ou focus (remplacez strangulation par gel de l'esprit et/ou chaine de glace pour avoir une autre macro utile)
#showtooltip
/cast [nomod, @target][mod:alt, @focus] Strangulation

. Permet de recroqueviller votre goule et de la laisser sur place :
/cast Recroquevillement
/petstay


. Permet de stun la cible avec la goule :
/cast Bondir
/cast Ronger


. Permet de faire bondir la goule près de vous, votre coéquipier ou votre cible :
/cast [nomod, @player][mod:alt, @party1][mod:ctrl, @target] Bondir

. Permet de se voile mortel ou son pet :
/cast [nomod, @player][mod:alt, @pet] Voile mortel(Rang 5)

. Permet d'explosion morbide sa goule :
/cast [target=pet] Explosion morbide(Rang 1)

. Permet d'invoquer sa gargouille et d'ordonner à vos familiers d'attaquer votre cible :
/cast Invocation d'une gargouille
/petattack


F) Paladin (Retribution/Sacré principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

 . Permet de mettre les "mains" sur son coéquipier (remplacez par chacune des mains pour faire différentes macros, sacrifice et liberté) :
#showtooltip
/cast [target=party1] Main de sacrifice

. Permet de stun la cible ou le focus (remplacez le marteau de justice par repentir pour obtenir une autre macro utile) :
#showtooltip
/cast [nomod, @target][mod:alt, @focus] Marteau de la justice(Rang 4)

. Permet de lancer le guide de lumière sur soi ou son coéquipier :
#showtooltip
/cast [nomod, @player][mod:alt, @party1] Guide de lumière

. Permet de lancer exorcisme sur un ennemi et un soin rapide sur un allié :
#showtooltip
/cast [harm] Exorcisme(Rang 9)
/cast [help] Eclair lumineux(Rang 9)

.Permet d'horion sacré sur soi :
#showtooltip Horion sacré(Rang 7)
/cast [target=player] Horion sacré(Rang 7)

. Permet de lancer épuration sur soi ou son coéquipier (remplacez épuration par purification ou bouclier saint pour obtenir une autre macro très utile) :
#showtooltip
/cast [nomod, @player][mod: alt, @party1] Epuration

. Permet de lancer supplique divine et de la cover par main de salut :
#showtooltip Supplique divine
/castsequence reset=60 [@player] Supplique divine, Main de salut

. Permet de renvoi du mal en priorité la gargouille :
#showtooltip Renvoi du mal
/targetexact Gargouille d'ébène
/cast Renvoi du mal
/targetlasttarget


F) Rogue (Finesse principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de spam son camouflage sans le break jusqu'à ce que vous utilisiez un modifier (alt/ctrl/shift/maj)
#showtooltip
/cast [nocombat] !Camouflage
/cancelaura [modifier] Camouflage

. Macro sap contre unité camouflée :
#showtooltip Assommer(Rang 4)
/console targetNearestDistance 10.000000
/targetenemy [noharm][dead]
/console targetNearestDistance 41.000000
/cast [harm,nodead] Assommer(Rang 4)

. Permet de sap focus :
#showtooltip Assommer(Rang 4)
/cast [target=focus] Assommer(Rang 4)

. Permet de pas de l'ombre le target ou le focus :
#showtooltip Pas de l'ombre
/cast [nomod, @target][mod:alt, @focus] Pas de l'ombre

. Permet de pas de l'ombre focus et kick dans la même macro :
#showtooltip Pas de l'ombre
/cast [target=focus] Pas de l'ombre
/cast [target=focus] Coup de pied

. Permet de passer en target le mouseover et de pas de l'ombre dessus :
#showtooltip
/target mouseover
/cast [@mouseover] Pas de l'ombre

. Permet d'utiliser les cds non utilisés si il en reste avant de préparation :
#show Préparation
/cast [nostealth] Evasion(Rang 2)
/stopcasting
/cast Sprint(Rang 3)
/stopcasting
/cast Préparation

. Permet de Vanish (et évite les accidents de coup blancs partis dans le même delay que le vanish) :
/stopattack
/cast Disparition(Rang 3)
/stopattack

. Permet de coup bas l'ennemi le plus proche (remplacez le coup bas par cécité pour avoir une autre macro de réaction, attention cependant cette macro n'est pas viable/fiable à spam en arène si vous avez plusieurs ennemis à proximité) :
#showtooltip Coup bas
/console targetNearestDistance 10.000000
/targetenemy [noharm][dead]
/console targetNearestDistance 41.000000
/cast [harm,nodead] Coup bas

. Permet de préméditation et de coup bas dans la même macro (remplacez coup bas par le garrot pour avoir une autre macro intéressante) :
#showtooltip Coup bas
/cast Préméditation
/cast Coup bas

. Permet de préméditation et stun le focus dans la même macro :
#showtooltip Coup bas
/cast [target=focus] Préméditation
/cast [target=focus] Coup bas

. Permet de préméditation et d'embuscade et d'initier les auto attacks :

#showtooltip Embuscade(Rang 10)
/cast Préméditation
/cast Embuscade(Rang 10)
/startattack

. Permet de disarm le target ou le focus :
#showtooltip Démantèlement
/cast [nomod, @target][mod:alt, @focus] Démantèlement

. Permet de kriss focus (et si vous perdez votre target de le retrouvez en appuyant une deuxième fois)
#showtooltip Kriss
/targetlasttarget
/cast [target=focus] Kriss

. Permet de gouge target (remplacez le Suriner par Cécité pour avoir une autre macro intéressante) : 
#showtooltip Suriner
/stopattack
/cast Suriner

. Permet de gouge focus (remplacez le Suriner par Cécité ou le kick "Coup de pied" pour avoir une autre macro intéressante) :
#showtooltip Suriner
/cast [target=focus] Suriner

. Permet de danse et de stun directement :
/cast Danse de l'ombre
/cast Préméditation
/cast Coup bas

. Permet de ficelle du métier son coéquipier :
/cast [target=party1] Ficelles du métier

. Permet de spam sa macro distraction sans perdre la zone :
/cast !Distraction
 
Répondre
#3
F) Chasseur (Spé MM "précision" principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de claquer ces cds de burst dans une même macro (vous pouvez rajouter un /use "trinket" avec activable) :
#showtooltip Tir rapide
/cast Ordre de tuer
/cast Tir rapide

. Permet de dissua et de cancel sa dissua dans la même macro (attention au spam) :
#showtooltip Dissuasion
/cast Dissuasion
/cancelaura Dissuasion

. Permet de scatter son target ou son focus tout en ne la cassant pas :
#showtooltip Flèche de dispersion
/stopattack
/petpassive
/cast [nomod, @target][mod:alt, @focus] Flèche de dispersion

. Permet de piège givrant en faisant attention à ne pas le casser (remplacez piège givrant par flèche givrante pour avoir une autre macro intéressante) :
/petpassive
/stopattack
/cast Piège givrant(Rang 3)

. Permet d'effrayer une bête en target ou focus (remplacez effrayer la bête par coupure d'aile, tir tranquillisant ou trait de choc et vous avez une autre macro intéressante) :
#showtooltip Effrayer une bête(Rang 3)
/cast [nomod, @target][mod:alt, @focus] Effrayer une bête(Rang 3)

. Permet de soigner et diriger son familier :
/cast Guérison du familier(Rang 10)
/petfollow


. Permet de faire tanker son familier :
#showtooltip Dérobade
/cast Dérobade
/petstay

. Permet de flèche baillon focus (remplacez la flèche-bâillon par n'importe quelle morsure "vipère, scorpide, serpent" pour avoir une autre macro intéressante :
/cast [target=focus] Flèche-bâillon

. Permet d'appel du maître sur soi ou son coéquipier :
#showtooltip Appel du maître
/cast [nomod, @player][mod:alt, @party1] Appel du maître


. Permet de spam fusée éclairante sans perdre la zone :
/cast !Fusée éclairante

Macros à familiers :

. Permet de rugissement de sacrifice soi ou son coéquipier :
#showtooltip Rugissement de sacrifice
/cast [nomod, @player][mod:alt, @party1] Rugissement de sacrifice


. Permet de grondement le target ou le focus :
#showtooltip Grondement(Rang 9)
/cast [nomod, @target][mod:alt, @focus] Grondement(Rang 9)

. Permet de grondement la cible la plus proche :
#showtooltip Grondement(Rang 9)
/console targetNearestDistance 10.000000
/targetenemy [noharm][dead]
/console targetNearestDistance 41.000000
/cast [harm,nodead] Grondement(Rang 9)

. Permet d'utiliser la technique spéciale du familier sur le target ou le focus :
#showtooltip "Sort du familier"
/cast [nomod, @target][mod:alt, @focus] "Sort du familier"


Familiers tenacité :

. Permet de s'interv soi ou son coéquipier :
#showtooltip Intervention
/cast [nomod, @player][mod:alt, @party1] Intervention


. Permet de charge le target ou le focus :
#showtooltip Charge
/cast [nomod, @target][mod:alt, @focus] Charge


. Permet d'intégrer le dernier rempart à la macro tanky du pet :
#showtooltip Dernier rempart
/cast Dernier rempart
/cast Dérobade
/petstay

Familiers ruse :
. Permet d'utiliser le "trinket" du familier :
#showtooltip Tête de taureau
/cast Tête de taureau

. Permet d'utiliser le rugissement de récupération (si vous l'avez pris) :
#showtooltip Rugissement de récupération
/cast Rugissement de récupération

. Permet d'utiliser le sprint du pet si vous l'avez pris :
#showtooltip Célérité
/cast Célérité


G) Démo (destru/affli principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

. Permet de fel dom les pets selon le modifier utilisé (en nomod c'est le chasseur corrompu) :
/cast Domination corrompue
/cast [mod:alt] Invocation : succube(Invocation); [mod:ctrl] Invocation : marcheur du Vide(Invocation); Invocation : chasseur corrompu(Invocation)


. Permet de fear target ou focus (remplacez avec bannir ou voile mortel pour avoir une autre macro utile)
#showtooltip Peur(Rang 3)
/cast [nomod, @target][mod:alt, @focus] Peur(Rang 3)

. Permet de malédiction des langages focus (remplacez par n'importe quel autre malé pour avoir une autre macro utile) :
/cast [target=focus] Malédiction des langages(Rang 2)

. Permet de soigner son familier et de le ramener :
/petfollow
/cast Captation de vie(Rang 9)


. Permet de corruption mouseover en priorité ou target (et si vous n'avez pas de cible, prend l'ennemi le plus proche)
#showtooltip Corruption(Rang 10)
/startattack
/cast [target=mouseover, exists][target, exists] Corruption(Rang 10)

. Permet de brûlure de l'ombre mouseover en priorité ou target :
#showtooltip Brûlure de l'ombre(Rang 10)
/cast [target=mouseover, exists][target, exists] Brûlure de l'ombre(Rang 10)

. Permet de spam furie de l'ombre sans perdre la zone (remplacez furie par pluie de feu pour une autre macro utile) :
/cast !Furie de l'ombre(Rang 5)

Macros familiers :
Chasseur corrompu :
. Permet de cs target :
/cast verrou magique

. Permet de cs focus :
/cast [target=focus] verrou magique

. Permet de se dispell soi même :
/cast [target=player] Dévorer la magie(Rang 7)

. Permet de dispell son coéquipier (remplacez # par 1/2/3/etc selon le coéquipier à dispell voulu) :
/cast [target=party#] Dévorer la magie(Rang 7)

. Permet de dispell offensif :

/cast [nomod, @target][mod:alt, @focus] Dévorer la magie(Rang 7)

Succube :
. Permet de succube target :
/cast Séduction

. Permet de succube focus :

/cast [target=focus] Séduction

. Permet de succube votre target et de le mettre en focus puis de succube votre focus si il est en vie (sinon passe votre target en focus et le succube) :
#showtooltip Séduction
/castrandom [@focus, exists, nodead][] Séduction, Séduction
/stopmacro [@focus,exists,nodead]
/focus [@target, exists, nodead]

Marcheur du vide :
. Permet de shield marcheur :
/cast Sacrifice(Rang 9)

. Permet de chercher les unités furtives :
/cast Consumer les ombres(Rang 9)


H) Guerrier (Armes principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

La plupart des macros du war nécessitent de mettre les armes que vous possédez, il faudra donc remplacer "arme à deux mains", "arme à une main", "bouclier" par votre équipement.
La plupart des macros war armes pvp ont une /cancelaura tempête de lames (et main de protection) ce qui permet de cancel votre bladestorm si vous les utilisez.

. Permet de passer en posture de combat et d'équiper son arme 2M :
/cancelaura Tempête de lames
/cast Posture de combat

/equip "arme à deux mains"

. Permet de passer en posture berserker et d'équiper son arme 2M :
/cancelaura Tempête de lames
/cast Posture berserker
/equip "arme à deux mains"

. Permet de passer en posture défensive et d'équiper son arme 1M/bouclier :
/cancelaura Tempête de lames
/cast  Posture défensive
/equip "arme à une main"
/equip "bouclier"

. Permet de changer en stance de combat et de charge le target ou le focus :
#showtooltip Charge(Rang 3)
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/cast [stance:2/3] Posture de combat
/cast [nomod, @target][mod:alt, @focus] Charge(Rang 3)

. Permet de changer en stance zerk et d'intercept le target ou le focus :
#showtooltip Interception
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/cast [stance:1/2] Posture berserker
/cast [nomod, @target][mod:alt, @focus] Interception

. Permet de renvoi des sorts :
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/equip [noequipped:shields] "Arme une main"
/equip [noequipped:shields] "Bouclier"
/cast Renvoi de sort

. Permet de renvoi des sorts même en stance zerk :
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/cast [stance:3] Posture défensive
/equip [noequipped:shields] "Arme une main"
/equip [noequipped:shields] "Bouclier"
/cast Renvoi de sort

. Permet de tempête des lames :
#showtooltip Tempête de lames
/cancelaura Main de protection(Rang 3)
/equip [noequipped:two-hand] "Arme à deux mains"
/cast Tempête de lames

. Permet de disarm target ou focus :
#showtooltip Désarmement
/cancelaura Tempête de lames
/cast [stance:1/3] Posture défensive
/cast [nomod, @target][mod:alt, @focus] Désarmement

. Permet de de kick target ou focus avec le bouclier :
#showtooltip Coup de bouclier
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/equip [noequipped:shields] Fendoir du gladiateur courroucé
/equip [noequipped:shields] Grand pavois du gladiateur courroucé
/cast [nomod, @target][mod:alt, @focus] Coup de bouclier

. Permet de kick avec la stance zerk :
#showtooltip Volée de coups
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/cast [stance:1/2] Posture berserker
/cast [nomod, @target][mod:alt, @focus] Volée de coups

. Permet d'intervention le mouseover priorité ou un coéquipier (remplacez # par 1/2/3/etc pour choisir le coéquipier voulu)
#showtooltip Intervention
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/cast [stance:1/3] Posture défensive
/cast [target=mouseover, exists][target=party#] Intervention

. Permet de rage berserker même si vous avez la regen enrage (cancel la regen) :
#showtooltip Rage berserker
/cancelaura Régénération enragée
/cast Rage berserker

. Permet de fear target ou focus :
#showtooltip Cri d’intimidation
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/stopattack
/cast [nomod, @target][mod:alt, @focus] Cri d’intimidation

. Permet de lancer fracassant :
#showtooltip Lancer fracassant
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/cast [stance:2/3] Posture de combat
/cast Lancer fracassant

. Permet de lancer le mur protecteur (premier appui équipe les armes, deuxième appui passe en stance def, troisieme appui lance le mur protecteur), remplacez mur protecteur par maîtrise du blocage pour avoir une deuxième macro utile :
#showtooltip Mur protecteur
/cancelaura Tempête de lames
/cancelaura Témérité
/equip [noequipped:shields] "Arme une main"
/equip [noequipped:shields] "Bouclier"
/cast [stance:1/3] Posture défensive
/cast Mur protecteur

. Permet de swap l'arme 2M par l'arme 1M/shield (un appui pour changer l'arme, l'autre pour la remettre) :
/equip "Arme deux mains"
/equip "Arme une main"
/equip "Bouclier"

. Permet de de fulgurance :
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/cast [stance:2/3] Posture de combat
/cast Fulgurance
/startattack

. Permet de poser la Mortal Strike :
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/cast Frappe mortelle(Rang 8)
/startattack

. Permet de poser le slow sur target ou focus :
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/cast [nomod, @target][mod: alt, @focus] Brise-genou

. Permet de pourfendre mouseover en prio puis target ou focus :
#showtooltip Pourfendre(Rang 10)
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/cast [target=mouseover, exists][nomod, @target][mod:alt, @focus] Pourfendre(Rang 10)

. Permet de témérité :
#showtooltip Témérité
/cancelaura Main de protection(Rang 3)
/cancelaura Tempête de lames
/cast [stance:1/2] Posture berserker
/cast Témérité

. Permet de retail :
#showtooltip Représailles
/cancelaura Tempête de lames
/cancelaura Main de protection(Rang 3)
/cast [stance:2/3] Posture de combat
/cast Représailles


I) Druide (Restau/Feral principalement)
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">

Pour les macros de feral, n'hésitez pas à remplacez Mutilation par Lambeau ou vice versa selon la spé que vous jouez.

. Permet de morph/demorph feral :
#showtooltip Forme de félin(Changeforme)
/cancelform [noform:2]
/castsequence reset=0.5 !Forme de félin(Changeforme)

. Permet de morph en forme humaine :
#showtooltip
/cancelaura [nomod, stance:1] Forme d'ours redoutable(Changeforme)
/cancelaura [nomod, stance:3] Forme de félin(Changeforme)
/cancelaura [nomod, stance:4] Forme de voyage(Changeforme)

. Permet de bond félin target ou focus :
#showtooltip Charge farouche (félin)
/cast [nostance:3] Forme de félin(Changeforme)
/cast [stance:3, nomod] Charge farouche (félin)
/cast [stance:3, mod:alt, @focus] Charge farouche (félin)

. Permet de charge ours target ou focus :
#showtooltip Charge farouche (ours)
/cast [nostance:1] Forme d'ours redoutable(Changeforme)
/cast [stance:1, nomod] Charge farouche (ours)
/cast [stance:1, mod:alt, @focus] Charge farouche (ours)

. Permet de stun ours target ou focus :
#showtooltip
/cast [mod:alt, @focus][] Sonner(Rang 3)

. Permet de se camoufler en forme de félin et de spam la macro sans break :

#showtooltip Rôder
/cast [nostance:3] Forme de félin(Changeforme); !Rôder

. Spécial elfe de la nuit pour camouflage dans l'ombre et se camoufler de nouveau sans break :
#showtooltip Camouflage dans l'ombre(Raciale)
/stopattack
/stopcasting
/use Camouflage dans l'ombre(Raciale)
/use [stance:1/2/4/5][nostance]!Forme de félin(Changeforme)
/use [stance:3]!Rôder

. Permet de stun en forme camouflé ou de mutilation hors camouflage :
/use [nostealth]Mutilation (félin)(Rang 5);Traquenard(Rang 5)
/startattack [nostealth]

. Permet de ravage en fufu et de griffure hors du fufu :

/cast [stealth] Ravage(Rang 7)
/cast [nostealth] Griffure(Rang 7)


. Permet de lancer les lucioles selon votre stance :
#showtooltip
/cast [stance:3] Lucioles (farouche)
/cast [stance:1] Lucioles (farouche)
/cast [stance:2/4/5][nostance] Lucioles

. Permet de lancer lucioles en mouseover puis en focus (remplacez Lucioles farouche par Lucioles selon votre spé) :
/cast [target=mouseover, exists][target=focus] Lucioles (farouche)

. Permet de clone target ou focus (remplacez clone par hibernation pour une autre macro utile) :
#showtooltip
/cast [mod:alt, @focus][] Cyclone


. Permet de mettre le dispell poison sur soi ou son coéquipier (remplacez le # par 1/2/3/etc selon le coéquipier voulu), si vous mettez délivrance de la malédiction à la place de Abolir le poison vous avez une autre macro utile :
#showtooltip
/cast [nomod, @player][mod:alt, @party#] Abolir le poison

. Permet de cast un Toucher guérisseur (utile pour l'instant en feral) :
/cancelform
/cast [stance:3] !Toucher guérisseur(Rang 15)
/cast Toucher guérisseur(Rang 15)

. Permet de NS heal (remplacez le soin par un clone ou une hibernation pour avoir une macro contrôle instant utile) :
#showtooltip
/cast Rapidité de la nature
/cast Toucher guérisseur(Rang 15)

. Permet de fleur de vie mouseover en priorité, puis la cible si elle existe, si pas de cible, heal le joueur (et avec alt heal le party choisi en remplaçant # par 1/2/3/etc). Remplacez fleur de vie par n'importe quel autre sort de soin pour avoir d'autres macros utiles :
#showtooltip Fleur de vie(Rang 3)
/cast [target=mouseover, exists][nomod, @target, exists][nomod, @player][mod:alt, @party#] Fleur de vie(Rang 3)


. Permet de spam ouragan sans perdre la zone :
/cast !Ouragan(Rang 5)

. Permet de regen frénétique :
#showtooltip Régénération frénétique
/cast [nostance:1] !Forme d'ours redoutable(Changeforme)
/cast Enrager
/cast Régénération frénétique
 
Répondre
#4
C'est tout à fait le guide que je me suis mis en tête de chercher (mais genre, plus tard). Mais le trouver en français, sans chercher, c'est royal. Du coup, bookmark immédiat. Un grand merci...

Fuck yeah, même.

[Image: tenor.gif?itemid=5706663]
 
Répondre
#5
Très beau travail  , tu es un vrai héro  . Oh Oh Oh Rolleyes Biggrin
 
Répondre
#6
Grand merci pour ton compendium !!!!! tout ce qu'il pour pvp dans de bonne conditions!!!!
Merci pour ton travail encore =^))
 
Répondre
#7
Franchement mec, tu t'fais vraiment suer pour rien.
 
Répondre
#8
(09-26-2019, 07:19)HasHtaGceNsuRe a écrit : Franchement mec, tu t'fais vraiment suer pour rien.

Pas vraiment, si ça peut servir à au moins 2/3 personnes je me suis pas fait suer pour rien.
Surtout que ça me coûte rien et ça me permet d'avoir mes macros centralisés sur un post forum quand je swap de serv au lieu de devoir co mes comptes
Guide de macros PvP :
https://www.paragon-servers.com/upload/f...c9f901.png) repeat-x;">
 
Répondre
  


Atteindre :


Browsing: 1 visiteur(s)